formateur informatique

Planning Excel automatique pour le salarié et ses congés

Accueil  >  Bureautique  >  Excel  >  Excel Avancé  >  Planning Excel automatique pour le salarié et ses congés
Livres à télécharger


Pour partager cette vidéo sur les réseaux sociaux, voici son url absolue :

Pour l'intégrer sur votre site internet ou blog, vous pouvez l'embarquer :

Sujets et formations similaires :


Plannings des salariés intégrant les congés

Dans cette formation Excel, nous proposons de terminer la construction automatisée du planning des jours travaillés, pour le salarié désigné. Dans une formation précédente, nous étions parvenus à reproduire la suite logique des jours ouvrables selon le mois choisi, par le biais d'une liste déroulante :

Planning Excel des jours travaillés construit automatiquement



Grâce à la fonction Excel Serie.Jour.Ouvre.Intl, nous avons automatiquement exclu les jours de Week-End ainsi que les jours fériés, recensés dans un tableau annexe. L'astuce a consisté à incrémenter d'une journée, la suite logique des dates pour le mois sélectionné. Ainsi, en partant du jour précédent le début du mois, la fonction s'est chargée de restituer les dates purgées des Week-End et jours fériés. Un calcul intermédiaire a permis de repérer les dates uniques pour en faciliter l'extraction. Les fonctions de recherche Index et Equiv, sur la base de ces repères incrémentés, ont automatiquement restitué ces dates ouvrables pour la construction du planning.

Extraire uniquement les jours ouvrables sur suite logique de dates par calcul Excel

Désormais nous devons intégrer les jours de congés, selon le salarié concerné par la construction du planning. Ces congés sont recensés pour chacun, dans une troisième feuille.

Dans le tableau de référence des jours fériés, il s'agira d'importer les dates de congés selon le nom du salarié choisi dans la liste. A l'issue, une mise en forme conditionnelle pertinente mettra en valeur les ruptures dus aux congés et aux Week End, dans deux couleurs différentes, afin de simplifier la lecture et la compréhension du planning.

Extractions dynamiques des jours de congés du salarié pour construction automatique du planning de travail

La capture ci-dessus illustre une intégration dynamique par calculs Excel, des jours de congés, dans le tableau de référence des dates non travaillées.

Source et présentation de la problématique
Pour améliorer le planning Excel, afin d'assurer sa construction automatisée, nous avons besoin de récupérer les travaux, là où nous les avions laissés. Ce classeur est constitué de trois feuilles. La dernière, nommée Salaries, énumère les congés de tous les employés en colonnes.

Tableau Excel listant les congés des salariés pour exclure ces jours du planning de travail

La deuxième feuille, nommée Jours-feries, liste les jours fériés recensés sur plusieurs années. Vous notez la présence de la dernière colonne. Elle est vide. C'est elle qui est destinée à recevoir dynamiquement les jours de congés du salarié sélectionné.

Enfin, la première feuille, nommée Jours-ouvres, est celle du planning. C'est sur cette base déjà fonctionnelle que nous devons apporter les évolutions.
  • A l'aide de la liste déroulante en B2, choisir le mois d'Août par exemple,
Un temps de calcul est nécessaire du fait de l'imbrication de toutes les fonctions d'extraction dans les formules intermédiaires.
  • A l'aide de la liste déroulante en D2, choisir l'année 2022 par exemple,
Construction automatique du planning de travail sur les jours ouvrables avec exclusion des jours fériés

Comme vous le constatez, la suite logique des dates de travail se construit automatiquement, pour l'année et le mois choisis. Les Week-End sont exclus de l'énumération et comme l'indique la capture, les jours fériés, ici le 15 Août, sont bien considérés comme des jours non travaillés. Ils sont donc chassés de la liste.

Si vous choisissez un employé avec la troisième et dernière liste déroulante, aucune incidence n'est produite pour l'instant sur la construction du Planning. Il s'agit de l'enjeu de cette formation, entre autres. Ce défi précieux pour de nombreuses entreprises, consiste à intégrer de façon automatisée, les dates de congés des salariés, pour produire un planning de travail en quelques clics.

Vous repérez la présence des calculs intermédiaires entre les colonnes R et T. A partir de la cellule R3, nous avions produit la date précédent le début du mois sélectionné, grâce à la fonction Excel Date :

=DATE(D2; RECHERCHEV(B2; Y:Z; 2; FAUX); 1) - 1

Sur cette base, à partir de la cellule suivante en R4, nous avions reconstruit la suite logique, par incrémentation d'une journée :

=R3 + 1

En colonne S, à partir de la cellule S3, nous avions exploité la fonction Excel Serie.Jour.Ouvre.Intl, sur cette suite logique, pour produire tous les prochains jours ouvrables :

=SERIE.JOUR.OUVRE.INTL(R3; 1; 1; 'Jours-feries'!$C$5:$I$35)

Vous notez à ce titre, la référence au tableau des jours fériés en troisième argument ('Jours-feries'!$C$5:$I$35). C'est la raison pour laquelle les jours ouvrables calculés, les chassent naturellement de l'énumération. Par anticipation, nous avions inclus la colonne dans laquelle doit se produire l'intégration dynamique des congés payés de l'employé.

Enfin, en colonne T, à partir de la cellule T3, un calcul de repérage nous avait permis d'identifier toutes les dates uniques, par un numéro incrémenté.

=SI(NB.SI($S$2:S2; S3)>0; ''; MAX($T$2:T2) + 1)

Et c'est sur la recherche de ces valeurs incrémentées que nous avions produit l'extraction des dates de travail, en colonne B, pour la construction automatique du planning.

=SIERREUR(INDEX(S:T; EQUIV(LIGNE(A1); T:T; 0); 1); '')



Limiter l'énumération aux dates du mois
Nous devons commencer par borner les dates listées, aux jours du mois sélectionné.

Enumération des dates pour le planning automatique Excel ne doit pas dépasser la fin du mois

Dans le contexte en cours, pour le mois d'Août 2022, l'énumération se poursuit au-delà du dernier jour du mois, comme l'illustre la capture ci-dessus. Nous pourrions corriger ce défaut directement depuis la formule d'extraction, en colonne B. Mais il est encore plus simple d'agir à la source. Le calcul qui est précisément concerné, est celui du repérage des dates ouvrables uniques par des numéros incrémentés. Jusqu'alors il se contente de conserver la cellule vide lorsque la date a déjà été marquée. Nous devons faire de même si la limite du mois est dépassée. Comme il suffit que l'une de ces deux conditions soit vérifiée, nous devons adapter la zone de critère de la fonction SI. La fonction Excel Ou imbriquée permet d'énumérer les conditions selon lesquelles l'action est à engager.
  • En cellule T3, adapter la formule de repérage comme suit :
=SI(OU(NB.SI($S$2:S2; S3)>0;TEXTE(S3;'mmmm')<>$B$2); ''; MAX($T$2:T2) + 1)

Nous conservons le précédent critère de dénombrement avec la fonction Nb.Si. Mais nous l'imbriquons dans une fonction Ou. De fait, nous pouvons additionner la condition sur la limite du mois, dans l'énumération. Et c'est la fonction Texte qui désigne la date à analyser, celle de la colonne précédente pour la ligne en cours (S3). Comme son nom l'indique, elle transforme en chaîne de caractères, l'information qui lui est passée, selon le format défini en second argument. Nous l'avions mise en oeuvre selon le même principe, dans la formation Excel sur les calculs de dates et d'heures. Avec le format mmmm, nous récupérons seulement l'information textuelle sur le mois, pour la date en cours. Le critère consiste à vérifier si ce mois restitué est différent de celui choisi dans la liste déroulante (<>$B$2). Notez la présence des dollars impératifs pour figer cette cellule de référence. En effet, ce calcul est destiné à être répliqué sur les lignes du dessous. Et pour chaque date, la comparaison des mois doit se faire immuablement par rapport à cette cellule B2. Elle ne doit donc pas bouger. Les modifications apportées à la formule sont repérées en caractères gras dans la syntaxe ci-dessus.

Lorsque l'une ou l'autre des conditions énumérées dans la fonction Ou est vérifiée, comme l'indique la branche Alors de la fonction Si (''), la cellule du résultat est gardée vide. En conséquence, lorsque la limite du mois est dépassée, le repérage numérique doit être stoppé.
  • Après avoir validé les modifications, double cliquer sur la poignée de la cellule du résultat, pour reproduire la logique du calcul sur l'ensemble des dates énumérées,
Si vous faites défiler l'affichage de la colonne T vers le bas, vous constatez que le marquage numérique se stoppe en effet au changement de mois. Comme les calculs de recherche en colonne B réalisent l'extraction sur ces repères incrémentés, la reconstruction de la liste ne dépasse plus la limite du mois.

Suite logique des jours stoppée à la fin du mois par calculs Excel pour planning du salarié

La construction automatisée du planning est donc en train de poursuivre sa mise en forme.

Exclure les dates de congés du planning
Comme nous l'avons dit plus haut, le calcul intermédiaire mettant en oeuvre la fonction Serie.Jour.Ouvre.Intl en colonne S, considère la matrice de la feuille Jours-feries. Elle chasse donc naturellement de l'énumération, toutes les dates repérées comme fériées pour le mois et l'année sélectionnés. Nous devons y inclure dynamiquement les jours de vacances du salarié choisi. Les formules d'extraction étant bâties sur ces calculs intermédiaires, le planning se mettra automatiquement à jour dans sa construction. Les vacances concernent l'année 2019. En conséquence, nous devons adapter le contexte.
  • Avec la première liste déroulante en B2, choisir le mois de Juillet,
  • Avec la deuxième liste déroulante en D2, choisir l'année 2019,
Sur la feuille Salaries, les employés sont listés par ordre alphabétique sur la ligne 2, à partir de la colonne B. Leurs vacances respectives sont énumérées à partir de la ligne 3. Ces deux indications de lignes sont précieuses pour la suite. Vous allez le constater.
  • Cliquer sur l'onglet Jours-feries en bas de la fenêtre Excel pour activer sa feuille,
Notre calcul d'extraction dynamique doit intervenir à partir de la cellule I5. Il s'agit de restituer la liste des vacances du salarié sélectionné. C'est la fonction Adresse qui va répondre à notre demande. Cette dernière retourne les références d'une cellule en fonction d'un numéro de ligne et d'un numéro de colonne. Sa syntaxe est la suivante :

=Adresse(Numéro_de_ligne; Numéro_de_colonne)

Le numéro de ligne est donc le chiffre 3, comme nous l'avons évoqué précédemment. Nous devons le préciser sous forme de variable afin qu'il évolue en même temps que le calcul est répliqué. Nous exploiterons donc la fonction Ligne en lui passant une cellule de la troisième rangée. Durant la réplication, elle retournera ainsi la suite logique, soit le numéro 3 puis 4 etc... De fait, nous récupèrerons toutes les dates du salarié.

L'indice de colonne dépend de la position du salarié sur la ligne 2 de la dernière feuille. Nous devons donc rechercher son nom. C'est la fonction Excel Equiv qui permet de retourner l'indice de colonne d'une donnée cherchée.

En revanche, la fonction Adresse ne peut être exploitée seule et nous allons comprendre pourquoi.
  • Sélectionner une cellule arbitraire de la feuille Jours-feries, par exemple J5,
  • Taper le symbole = pour débuter le calcul temporaire,
  • Saisir la fonction retournant les références d'une cellule suivie d'une parenthèse, soit Adresse(,
  • Taper le chiffre 5 pour désigner une cellule de la cinquième ligne,
  • Taper un point-virgule (;) pour passer dans l'argument du numéro de colonne,
  • Taper le chiffre 2 pour désigner une cellule de la colonne B,
  • Fermer la parenthèse de la fonction Adresse et valider la formule,
Nous obtenons en retour les références de la cellule située au croisement de la cinquième ligne et de la deuxième colonne, soit $B$5. La formule que nous avons saisie est la suivante :

=ADRESSE(5;2)

Un souci de taille se dresse. L'information retournée n'est pas le contenu de la cellule désignée. Ces références sont considérées comme du texte par Excel. Elles ne sont donc pas exploitables pour le calcul. C'est la fonction Excel Indirect qui permet d'interpréter cette donnée pour exploiter ces références en tant que telles.
  • En cellule J5, modifier le calcul comme suit :
=Indirect(ADRESSE(5;2))

Cette fois, nous retournons bien l'information contenue dans la cellule B5. C'est ce procédé que nous devons mettre en oeuvre pour l'extraction des congés. Et comme nous l'avons dit plus haut, les numéros de ligne et de colonne doivent être des variables.
  • Supprimer le calcul en cellule J5,
  • Sélectionner la première cellule pour le calcul d'extraction, soit I5,
  • Taper le symbole = pour débuter la formule,
  • Saisir la fonction pour interpréter les références, suivie d'une parenthèse, soit Indirect(,
  • Saisir le nom de la feuille de recherche suivi d'un point d'exclamation entre guillemets, soit 'Salaries!',
  • Enfoncer la touche 1 en haut à gauche du clavier pour inscrire le caractère de concaténation, soit : &,
En effet, n'oublions pas que nous désignons des cellules qui ne sont pas situées sur la même feuille que le calcul. Comme l'impose la syntaxe Excel dans ce cas, nous devons préfixer les références par le nom de la feuille de destination, suivi d'un point d'exclamation.
  • Saisir la fonction retournant les références, suivie d'une parenthèse, soit Adresse(,
  • Saisir la fonction donnant la ligne d'une cellule, suivie d'une parenthèse, soit Ligne(,
  • Sélectionner une cellule de la troisième ligne, par exemple A3,
  • Fermer la parenthèse de la fonction Ligne,
  • Taper un point-virgule (;) pour passer dans l'argument du numéro de colonne,
  • Saisir le nom de la fonction retournant la colonne d'une donnée cherchée, suivi d'une parenthèse, soit Equiv(,
  • Cliquer sur l'onglet Jours-ouvres en bas de la fenêtre Excel pour activer sa feuille,
  • Taper la référence G2 pour désigner le salarié sélectionné par la liste,
  • Enfoncer la touche F4 du clavier pour la figer, ce qui donne : 'Jours-ouvres'!$G$2,
  • Taper un point-virgule (;) pour passer dans l'argument de la ligne de recherche,
  • Cliquer sur l'onglet Salaries en bas de la fenêtre Excel pour activer sa feuille,
  • Sélectionner l'intégralité de la ligne 2 en cliquant sur son étiquette, ce qui donne : Salaries!2:2,
  • Enfoncer la touche F4 pour figer cette plage de recherche dans le calcul,
  • Taper un point-virgule (;) suivi du chiffre 0, soit : ;0, pour réaliser une recherche selon une correspondance exacte,
  • Fermer la parenthèse de la fonction Equiv,
  • Fermer la parenthèse de la fonction Adresse,
  • Fermer la parenthèse de la fonction Indirect,
  • Valider la formule par le raccourci clavier CTRL + Entrée pour garder la cellule active,
  • Tirer la poignée du calcul jusqu'en ligne 40 par exemple pour être sûr de n'oublier aucune date,
Importer dates de congés du salarié pour construction automatisée du planning de travail

Comme vous le constatez, nous importons parfaitement la liste des congés pour le salarié sélectionné. De fait, ils sont d'ores et déjà considérés par les calculs intermédiaires bâtis en amont, et exclus dans la construction du planning par les calculs d'extraction.

Si vous changez de salarié avec la liste déroulante dans la feuille Jours-ouvres, vous constatez que les dates sont automatiquement actualisées dans la feuille Jours-feries. Si vous consultez le tableau de référence de la feuille Salaries, vous remarquez qu'elles correspondent à l'employé désigné.

Nos extractions de données sur la base d'une information de colonne variable, ont donc parfaitement fonctionné. La formule que nous avons construite est la suivante :

=INDIRECT('Salaries!'&ADRESSE(LIGNE(A3); EQUIV('Jours-ouvres'!$G$2; Salaries!$2:$2; 0)))

Dans l'énumération, lorsque la dernière date est atteinte, le calcul réplique une donnée incohérente : 00/01/1900. Il s'agit en fait de la valeur 0 qu'Excel essaie de transcrire au format date. Nous pouvons les conserver, elles ne parasiteront pas la construction du planning. Aucune période ne recoupera cette valeur.
  • Cliquer sur l'onglet Jours-ouvres en bas de la fenêtre Excel pour activer sa feuille,
Vous devez déjà constater une modification automatique dans la construction du planning, par rapport à l'état dans lequel nous l'avions laissé. Des jours ont été exclus de l'énumération. Il s'agit bien sûr des congés.
  • Sélectionner le mois de Mai à l'aide de la première liste déroulante,
  • Sélectionner l'année 2019 à l'aide de la deuxième liste déroulante,
  • Sélectionner l'employée Charline Galls à l'aide de la dernière liste déroulante,
Planning Excel de travail pour employé sans Week-End, jours congés et fériés

Comme vous le constatez, la construction automatisée du planning dédié au salarié fonctionne parfaitement. Les Week-End et jours fériés sont exclus naturellement. Vous notez l'absence des Mercredis 1er et 8 Mai notamment. Mais cela, nous le savions déjà.

Les semaines du Lundi 13 Mai et du Lundi 20 Mai ont complètement disparu. Si vous consultez la feuille des congés, vous remarquez qu'il s'agit en effet de vacances posées par le salarié.

La clé de ce succès réside dans l'extraction sur la base des résultats restitués par la fonction Serie.Jour.Ouvre.Intl. C'est bien elle qui offre la souplesse de définir les dates à exclure.



Mise en forme dynamique du planning
Pour parfaire l'application, il s'agit de l'agrémenter de certains réglages visuels dynamiques. Nous souhaitons repérer les ruptures dues aux congés posés en milieu de semaine. De même nous souhaitons repérer les ruptures dues aux jours de Week-End. Ainsi, nous identifierons plus facilement les semaines les unes par rapport aux autres. Nous faciliterons la lecture et la compréhension du planning. Nous proposons d'appliquer un remplissage bleu clair pour le premier cas et vert clair pour le second.

Toutes les lignes du planning sont potentiellement concernées. Comme vous le savez, il s'agit de bâtir une règle selon laquelle un format dynamique doit se déclencher. Pour le premier cas, nous devons vérifier si la date en colonne B est bien la suite logique de la précédente. Sinon, une rupture étant détectée, un remplissage bleu clair doit s'appliquer. Dans le même temps, nous devons nous assurer que la date en cours d'analyse n'est pas une cellule vide. Comme l'enseigne notamment le petit livre Excel pour débuter les calculs, c'est la fonction Excel Et qui permet de lister toutes les conditions à vérifier ensemble.
  • Sélectionner la plage de cellules B5:P35,
Nous prévoyons une sélection volontairement large afin de n'omettre aucune date selon les constructions contextuelles des plannings.
  • Dans le ruban Accueil, cliquer sur le bouton Mise en forme conditionnelle,
  • En bas de la liste qui apparaît, choisir Nouvelle Règle,
Nos critères sont en effet spécifiques. Il s'agit de vérifier les conditions par calculs.
  • Dans la boîte de dialogue qui suit, choisir le type : Utiliser une formule pour...,
  • Puis, cliquer dans la zone de saisie située juste en dessous,
  • Taper le symbole = pour démarrer la syntaxe du critère,
  • Saisir la fonction pour énumérer les critères, suivi d'une parenthèse, soit Et(,
  • Cliquer sur la toute première date du planning, soit la cellule B5,
  • Enfoncer deux fois la touche F4 du clavier pour ne conserver le dollar que devant la colonne, ce qui donne : $B5,
Un critère de mise en forme conditionnelle réagit de la même façon qu'un calcul. Il débute l'analyse sur la première cellule de la plage sélectionnée. Puis, il les parcourt toutes. Pour toutes les cellules d'une même ligne, la condition doit être posée sur la date en colonne B. Elle ne doit donc pas suivre le déplacement en colonne. Pour chaque ligne en revanche, le critère doit bien être vérifié sur la date située sur la même rangée. La cellule doit donc se déplacer vers le bas.
  • Taper le symbole supérieur (>) pour l'inégalité du critère à satisfaire,
  • Sélectionner la cellule située juste au-dessus de B5, soit B4,
  • Enfoncer deux fois la touche F4 du clavier pour les mêmes raisons que précédemment, ce qui donne : $B4,
  • Lui ajouter une unité, soit : +1,
La condition est la suivante: $B5>$B4+1. Nous cherchons à vérifier que la date en cours n'est pas le jour suivant de la date précédente. Dans ce cas en effet, une rupture est constatée et un format doit être déclenché. Mais une autre condition doit être satisfaite en même temps.
  • Taper un point-virgule (;) pour passer dans l'argument du critère suivant,
  • Sélectionner de nouveau la cellule B5 et la figer seulement en colonne, soit $B5,
  • Taper le symbole inférieur suivi du symbole supérieur, soit : <>, pour l'inégalité à vérifier,
  • Saisir deux guillemets, soit '',
Le second critère est le suivant : $B5<>''. Nous cherchons simplement à nous assurer que la cellule en cours d'analyse n'est pas vide. Il n'est en effet pas question d'appliquer des couleurs en dehors du planning.
  • Fermer la parenthèse de la fonction ET,
La syntaxe de la zone de critère est donc la suivante :

=Et($B5>$B4+1; $B5<>'')

Lorsque la cellule en cours n'est pas vide et que dans le même temps, la date n'est pas la suite logique de la précédente, nous devons mettre en valeur cette rupture par un fond bleu clair.
  • Pour ce faire, cliquer sur le bouton Format placé juste en dessous,
  • Dans la nouvelle boîte de dialogue qui suit, activer l'onglet Remplissage,
  • Dans la palette des couleurs, choisir un bleu clair et valider par Ok,
Nous sommes de retour sur la première boîte de dialogue qui confirme les réglages de mise en forme qui seront appliqués lorsque les conditions seront satisfaites.
  • Cliquer de nouveau sur Ok pour enclencher la mise en forme conditionnelle,
Repérer automatiquement et visuellement les débuts de semaines par la mise en forme conditionnelle Excel

Comme vous le constatez, à chaque fois qu'une date n'est pas la suite logique de la précédente, elle est repérée dynamiquement par les réglages de mise en forme conditionnelle. En revanche à ce stade, elle recoupe les deux règles que nous avions prévues. Les jours de Week-End provoquent une rupture déclenchant la vérification de la première condition.

Mais comme nous allons cumuler une seconde règle spécifique pour ces journées non travaillées, elle prendra le pas sur la première. C'est l'ordre d'empilement des règles de mise en forme conditionnelle qui importe. Dans la hiérarchie, pour une même plage de cellules, c'est la plus récente qui prend le pas sur les plus anciennes.

Il s'agit désormais de vérifier que le jour de semaine pour la date en cours est inférieur au jour de semaine pour la date précédente. Comme nous l'avait appris la formation Excel pour réaliser des opérations sur des dates, la fonction JourSem est dédiée pour ce type de vérification. Elle renvoie un chiffre qui correspond à la position du jour de la date dans la semaine. Il s'agit du chiffre 1 pour le Lundi par exemple et 5 pour le Vendredi. Donc nécessairement, lorsque nous vérifions que le premier est inférieur au second, nous savons que la semaine a changé et qu'un Week-End est intercalé.

Dans le même temps, comme précédemment, nous devons nous assurer que la cellule en cours d'étude n'est pas vide. La fonction Excel Et est donc toujours de mise.
  • Sélectionner de nouveau la plage de cellules B5:P35,
  • Cliquer sur le bouton Mise en forme conditionnelle du ruban Accueil,
  • En bas de la liste, choisir Nouvelle Règle,
  • Dans la boîte de dialogue qui suit, choisir le type : Utiliser une formule pour...,
  • Puis, cliquer dans la zone de saisie située en dessous pour l'activer,
  • Taper le symbole = pour débuter la syntaxe des critères,
  • Saisir la fonction pour recouper les conditions, suivie d'une parenthèse, soit : Et(,
  • Taper la fonction pour le jour de semaine d'une date, suivie d'une parenthèse, soit Joursem(,
  • Sélectionner la première date, soit B5,
  • Enfoncer deux fois la touche F4 du clavier pour la défiger en ligne, ce qui donne: $B5,
  • Fermer la parenthèse de la fonction JourSem,
  • Taper le symbole inférieur (<) pour l'inégalité à vérifier,
  • Saisir de nouveau la fonction pour le jour de semaine, suivie d'une parenthèse, soit : Joursem(,
  • Sélectionner la cellule B4 et la défiger en ligne, ce qui donne : $B4,
  • Fermer la parenthèse de la fonction Joursem,
La première condition à vérifier est désormais écrite. Sa syntaxe est la suivante :

Joursem($B5)<Joursem($B4)

Si elle est satisfaite, elle confirme que le jour de semaine pour la date en cours d'analyse, est inférieur au jour de semaine de la date précédente. En conséquence, nous savons qu'un Week-End est intercalé.
  • Taper un point-virgule (;) pour passer dans l'argument de la condition suivante,
  • Sélectionner de nouveau la première date et la défiger en ligne, ce qui donne : $B5,
  • Taper le symbole inférieur suivi du symbole supérieur, soit : <>, pour l'inégalité à vérifier,
  • Saisir deux guillemets ('') pour confirmer que la cellule n'est pas vide,
  • Fermer la parenthèse de la fonction Et,
La syntaxe du second critère est identique à celle de la première règle : $B5<>''. En même temps que la première condition est vérifiée, nous nous assurons que la cellule en cours n'est pas vide.

Lorsque toutes deux sont vérifiées ensemble, selon la syntaxe globale suivante :

=Et(Joursem($B5)<Joursem($B4); $B5<>'')

Nous devons attribuer un remplissage vert clair.
  • Pour cela, cliquer sur le bouton Format situé juste en dessous,
  • Dans la boîte de dialogue qui suit, activer l'onglet Remplissage,
  • Dans la palette des couleurs, choisir un vert clair et valider par Ok,
Nous sommes de retour sur la première boîte de dialogue qui confirme les attributs de mise en valeur à déclencher lorsque les conditions sont remplies.
  • Valider de nouveau par Ok pour activer cette seconde règle,
Mise en forme automatique des congés et Week End pour le planning Excel de travail

Comme vous le constatez, les deux ruptures dans l'énumération des dates, sont repérées explicitement et différemment. Les Lundis 6 et 27 Mai correspondent bien au commencement d'une nouvelle semaine. La rupture à cause des Week-End est donc clairement identifiée. Les Jeudis 9 et 31 Mai sont l'oeuvre des jours fériés. En 2019, l'Ascension tombe en effet le 30.

Les dates se construisent automatiquement selon trois critères : L'année, le mois et le salarié. Les Week-End, jours fériés et congés sont dynamiquement exclus par les formules d'extraction. Les ruptures sont automatiquement mises en forme. En conséquence, nous avons réussi à finaliser l'application de construction automatisée du planning des jours travaillés pour les employés. Nous pouvons simuler une dernière vérification.
  • A l'aide des listes déroulantes, construire le planning de travail du mois de Juillet 2019 pour l'employé Marie Rouana,
Planning automatique Excel des jours ouvrés et ouvrables travaillés

Cette personne a posé les trois premières semaines de Juillet. Elle ne débute donc le travail qu'à partir du 22. La rupture du seul Week-End intercalé est parfaitement mise en valeur. La clarté du planning automatique est idéale.

 
Sur Facebook
Sur G+
Sur Youtube
Les livres
Contact
Mentions légales



Partager la formation
Partager sur Facebook
Partager sur Google+
Partager sur Twitter
Partager sur LinkedIn